CMD日期查询,可以查询几天前或几天后的日期

::1、解决闰年、闰月的计算问题；
::2、可以跨年、跨月查询日期；
::3、用途：可以对若干日期以前或以后的文件进行操作处理...
::4、说明：算法源自willsort,其它由youxi01提供。

@echo off 
title CMD日期查询,可以查询几天前或几天后的日期 Edit by yongfa365 Make by Willsort 
color 1f 
if [%1]==[] call :Help 
call :Date2Day %1 days 
set/a days=%days%%2 
call :Day2Date %days% date 
echo. 
echo -----------结果--------------- 
echo. 
echo 你查询的日期为：%date% 
echo ------------------------------ 
cmd /k 

:Date2Day 
setlocal ENABLEEXTENSIONS 
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do ( 
set yy=%%a & set mm=%%b & set dd=%%c 
) 
set /a dd=100%dd%%%100,mm=100%mm%%%100 
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2 
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633 
endlocal&set %2=%j%&goto :EOF 

:Day2Date 
setlocal ENABLEEXTENSIONS 
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a 
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5 
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10 
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%) 
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF 

:Help 
cls 
echo ________________________________________________ 
echo 使用方法：%~nx0 [日期] [天数] 
::建议先运行一下，这样看到的才是真正的注释
echo. 
echo 日期格式：2007-03-31 
echo 天数格式：+/-查询的天数 
echo 示例1：%~nx0 2007-11-15 +3 就是查询2007-11-15的3天后的日期 
echo 示例2：%~nx0 2007-11-15 -3 就是查询2007-11-15的3天前的日期 
echo 示例3：
echo set date=%%date:~0,10%%
echo %~nx0 %%date%% -3 
echo 就是查询前3天的日期 
echo ________________________________________________ 
echo. 
cmd /k